Modern mobile applications with Qt and QML

English [French]

Modern Mobile Applications with Qt and QML

Qt is a flexible and powerful framework for creating cross-platform applications. QML is now part of Qt, providing a markup language which gives complete freedom in development of user interfaces.

A good way to see the power of Qt is to start coding with it. Let's write a simple application using Qt and QML. This will be an application I called 4Toddler; the application will start in full-screen mode and it has just two buttons placed in the top right corner of the window: About and Close. The main function is to display a random image with a fireworks effect and with a random sound effect.

The User interface will be written with QML; the backbone is written in Qt C+.

Create new project

If you do not have Qt already installed, visit Qt download page to download Qt SDK for your platform and install it.

Launch Qt Creator, select File -> New File or Project. In the new dialog select Qt C++ Project-> Qt Gui Application, and then click Choose…

screenshot

In the new window: type project name, select path to the project folder and then click Next.

screenshot

In the next window: uncheck Generate form option. We do not need to generate a form. Click Next

screenshot

In the last window: just click Finish.

The application skeleton is ready, now we can proceed to code the logic and design the UI.

Code core logic in C+

First we need to add the qt-declarative module to our project. This is the module that provides a widget in which a QML interface is displayed.

Open project file (4Toddler.pro) and append the line

QT ''= core gui

with declarative

QT''= core gui declarative

Now we need to change the base class for our main window. Replace QMainWindow with QDeclarativeView and include QDeclarativeView

#include <QDeclarativeView>
class MainWindow : public QDeclarativeView
{
  …
}

Also we need to cut off QMainWindow(parent) from the MainWindow constructor; we do not need this initialization anymore.

MainWindow::MainWindow(QWidget *parent)
{
  Init();
}

If you launch the application right now you will see an empty window. This is because we have not initialized or created our QML interface yet.

Add QML interface

Let's add a new file to our project: right click on the project in the projects explorer window.

Add New then select Qt section and Qt QML File in the templates list and click Choose…

Type the file name in the Name field, click Next then Finish in the next window.

The wizard will create and open the new QML file in the editor. There is just one Rectangle element inside it. This will be the root element for our user interface. Let's add some new properties to this element.

Note: some versions of Qt Creator will add a Hello World text element centered in the Rectangle. Remove the text element before proceeding.

Rectangle
{
  // ID of this element. Using this ID we can access the element and its properties from other elements
  id: canvas
  // Background color, black in this case
  color: "black"
  // Change sizes of this element to fill the parent
  anchors.fill: parent
  // Element can receive focus
  focus: true
}

There is nothing special for now, just black background.

Multilingual

During the remainder of this tutorial we will shift back and forth between QML and C++ development.

We need to add some initialization code for our QML interface by defining a new method inside the mainwindow.h file …

void Init();

.. And implementing it in the mainwindow.cpp file

void MainWindow::Init()
{
  // Path to the content folder
  QString contentPath;

  #ifdef QT_DEBUG
  // In the debug version of our project this is a path to the project folder
  contentPath = "D:/MyProjects/QT/4Toddler";
  #else
  // In the release version - path to the application folder
  contentPath = QApplication::applicationDirPath();
  #endif
  setFocusPolicy(Qt::StrongFocus);
  // Change QML document sizes to fit the main window
  setResizeMode(QDeclarativeView::SizeRootObjectToView);
  // Load QML file
  setSource(QUrl::fromLocalFile(contentPath + "/main.qml"));
}

Now we need to replace one line in the main.cpp file

int main(int argc, char *argv[])
{
  …
  w.show();
  …
}

With

int main(int argc, char *argv[])

{
  …
  w.showFullScreen();
  …
}

This will force our window to open in full-screen mode.

Structure code with components

Before we launch our application, let's add two buttons. One is to display About dialog and the second to Close our window. We do not need to implement buttons twice, we going to create a component and use it every time we need to add a new button by overriding just a few properties.

Let's add the new Qml file - WindowButton.qml to our project. Note the filename begins with a capital letter — this signifies it defines a QML component.

Image
{
  // ID of this element
  id: button
  // The MouseArea item enables simple mouse handling
  MouseArea
  {
    anchors.fill: parent
    id: mouseArea
    // On click call callback() handler
    onClicked: callback()
  }
}

Now we can add two buttons to our window

// Place items in row

Row
{
  // Right side of the item is anchored to the right side of the parent element
  anchors.right: parent.right
  // Right margin
  anchors.rightMargin: 4
  // Top side of the item is anchored to the top side of the parent element
  anchors.top: parent.top
  // Top margin
  anchors.topMargin: 4
  // Margins for children elements
  spacing: 4
  WindowButton
  {
    // Button to display the About dialog
    id: about
    // Path to background picture. This is a relative path to the path of this QML file
    source: "about.png"
    // Callback method, which will be called on mouse click
    // onClicked: callback()
    function callback() {}
  }
  WindowButton
  {
    // Button to close window
    id: exit
    source: "exit.png"
    function callback() {}
  }
}

Communicate between QML and C++

Now we should implement both callback() methods. To close the window we will call the Quit function of the main window. Now we will see how Qt and QML communicate. Methods will be implemented inside Qt and then called from the QML file.

Let's add a new function to the mainwindow.h header file

Q_INVOKABLE void Quit();

And implementation in mainwindow.cpp file

void MainWindow::Quit()
{
  QApplication::quit();
}

Now we need to "tell" QML about this method. Inside Init we should to add just one line:

rootContext()->setContextProperty("window", this);

Now we can access window object's functions declared as Q_INVOKABLE from QML. Window here is just an example, you could use any object name you want.

Let's add callback() function implementation to close button

function callback()
{
  window.Quit();
}

Visualize state and add animation

Ok, the application can be launched. Launch it and click the Close button. You see? State of the button is not changed after click; it looks like the button is just inactive. Let's add state changes for normal and clicked states.

Image
{
  …
  states:[
    State
    {
      // Name of the state
      name: "hovered"
      // When condition. Item will go to this state if condition is true
      // In this case on mouse click
      when: mouseArea.pressed
      // Which properties will be changed in that state
      // In this case- opacity
      PropertyChanges { target: button; opacity: 1}
    },
    State
    {
      name: "normal"
      // This state will be activated if mouse button is not pressed
      when: mouseArea.pressed == false
      PropertyChanges { target: button; opacity: 0.7; }
    }
  ]
}

Item will change state if the condition described in when property is true. You could change state manually by assigning state property. Let's launch the application again. Ok, this time it looks more active. We can make our button nicer by adding some animation.

Image
{
  …
  Behavior on opacity
  {
    // Animaion step is a 100 milliseconds
    // On every iteration opacity will increase or descrease with step equals to 0,1
    NumberAnimation { duration: 100 }
  }
}

The Behavior is a simple and flexible way to create animations. This element allows you to specify a default animation for a property change.

Launch the application and try to click on About or Close buttons. This looks much better!

We will implement the About dialog only using QML. Dialog will appear on the screen when About button is clicked and disappear when the user clicks inside the button or on the background.

Let's add About.qml file to our project.

// Parent element for dialog window
Rectangle
{
  id: about
  // Function to display dialog window
  // This function just changes opacity of the main element to 1
  function show() {
    about.opacity = 1
  }
  // Function to hide dialog window
  // This function just changes opacity of the main element to 0
  function hide() {
    about.opacity = 0
  }
  // Transparent background
  color: "transparent"
  // Opacity is 0 by default, dialog not visible
  opacity: 0
  // Anchors to parent width and height.
  width: parent.width
  height: parent.height
  // Element is visible if opacity > 0
  // opacity > 0
  visible: opacity > 0
  // Child element to create semitransparent background
  Rectangle
  {
    anchors.fill: parent
    opacity: 0.5
    color: "gray"
  }
  // Body of the dialog window
  Rectangle
  {
    id: dialog
    // Fixed width and height
    width: 360
    height: 230
    // To make dialog centered inside parent we need to calculate its x and y coordinates
    x: parent.width / 2 - dialog.width / 2
    y: parent.height / 2 - dialog.height / 2
    // Place dialog on top of other elements
    z: 10
    border.color: "gray"
    Text
    {
      text: "4 Toddler"
      font.bold: true
      font.pixelSize: 22
      anchors.horizontalCenter: parent.horizontalCenter
      anchors.verticalCenter: parent.verticalCenter
    }
  }
  Behavior on opacity
  {
    NumberAnimation { duration: 100 }
  }
  MouseArea
  {
    anchors.fill: parent
    // Hide dialog on mouse click
    onClicked: hide()
  }
}

Take a look at the line

visible: opacity > 0

As you can see, property can be assigned and can be calculated.

Let's add About dialog and callback() function implementation for the button About. In Main.qml file we need to declare the new About element.

Rectangle
{
  id: canvas
  ..
  About
  {
    id: aboutDlg
  }
}

And callback() function implementation

aboutDlg.show();

to

WindowButton
{
  id: about
  …
  function callback()
  {
    aboutDlg.show()
  }
}

Finally we need to implement the main functionality for our application.

The element to display a random icon on the screen will be an Image element. Let's add a new file for the new element - Block.qml

Image
{
  id: block;
  // New custom properties to change visibility of this element
  property bool remove: false
  property bool show: false
  opacity: 0
  fillMode: Image.Stretch
  states: [
    State
    {
      // State is used to remove element from the screen and destroy it
      name: "remove"; when: remove  true
      PropertyChanges { target: block; opacity: 0 }
      StateChangeScript { script: block.destroy(1000) }
    },
    State
    {
      // State is used to display element
      name: "show"; when: show  true
      PropertyChanges { target: block; opacity: 1 }
    }
  ]
  Behavior on opacity { NumberAnimation { duration: 300 } }
}

Now we need to implement the keyboard handler. Handler will be implemented with JavaScript. Let's add new main.js to our project.

// Template for new elements
var component = Qt.createComponent("block.qml")
// Max number of items on the screen
var maxBlocksCount = 10
// Array for the items
var blocksArray = new Array()
// Keyboard handler
function handleKey()
{
  // x coordinate is a random number from 0 to window with in pixels
  var x = Math.floor(Math.random() * canvas.width)
  // y coordinate is a random number from 0 to window height in pixels
  var y = Math.floor(Math.random() * canvas.height)
  // This function will create a new element on each call with random x and y coordinates
  createNewBlock(x, y)
}
// Function to create a new element
function createNewBlock(x, y)
{
  if(component.status != Component.Ready) {
    return false
  }
  // Remove items if number of items is more than maxBlocksCount
  if(blocksArray.length > maxBlocksCount) {
    removeAllBlocks()
  }
  var newBlock = component.createObject(canvas)
  if(newBlock == null) {
    return false
  }
  // Path to image is available via randomIcon property of the main window
  var iconFile = window.randomIcon
  newBlock.source = ("Icons/" + iconFile)
  newBlock.x = x
  newBlock.y = y
  // Change state to show
  newBlock.show = true
  blocksArray.push(newBlock)
  // Play random sound effect
  window.PlaySound()
  return true
}
// Function do remove all existings items
function removeAllBlocks() {
  for(var i = 0; i < blocksArray.length; +''i) {
    blocksArray[i].remove = true
  }
  while(blocksArray.length != 0) {
    blocksArray.pop()
  }
}

As you see in code above we should implement new property randomIcon and method PlaySound.

Let's add property declaration and method to access it to our mainwindow.h file.

Q_PROPERTY(QString randomIcon READ RandomIcon)

QString RandomIcon();

Implementation in mainwindow.cpp file

QString MainWindow::RandomIcon()
{
  QStringList iconFilesList;
  QString searchPath = m_ContentPath'' "/Icons/";
  QDir directory = QDir(searchPath);
  QStringList filters;
  filters << "'''.png";
  directory.setNameFilters(filters);
  // Get the list of the png files inside Icons directory
  iconFilesList = directory.entryList(QDir::AllEntries);
  // Generate random index of the element
  int fileIdx = qrand() % iconFilesList.count();

  // Return file name
  return iconFilesList.at(fileIdx);
}

Now we need to declare the method to play a random sound effect in mainwindow.h file

Q_INVOKABLE void PlaySound();

And implementation in mainwindow.cpp file

void MainWindow::PlaySound()
{
  QStringList soundFilesList;
  QDir directory = QDir(m_ContentPath + "/Sounds/");
  QStringList filters;
  filters << "'''.wav";
  directory.setNameFilters(filters);
  // Wav files list inside Sounds directory
  soundFilesList = directory.entryList(QDir::AllEntries);
  // Generate random index of the element
  int fileIdx = qrand() % soundFilesList.count();
  // File name
  QString soundFile = m_ContentPath + "/Sounds/" + soundFilesList.at(fileIdx);
  // Play file asynchronously
  QSound::play(soundFile);
}

Almost done. All we need is to add the keyboard handler to our parent QML element. But first we should include main.js file to main.qml file

import Qt 4.7
import "main.js" as Main

Keyboard event handler for root element

Rectangle
{
  id: canvas
  …
  Keys.onPressed: {
    if(event.isAutoRepeat == false) {
      Main.handleKey()
    }
  }
}

That's all! Now you can launch the application and try to press any key on the keyboard. But… I almost forgot about the fireworks effect.

Let's add a new file called Fireworks.qml. Why do we need a new file? Because this will be a reusable element, this will save time in the future.

import Qt.labs.particles 1.0
Particles
{
  id: particles
  width: 1
  height: 1
  anchors.centerIn: parent
  emissionRate: 0
  lifeSpan: 700
  lifeSpanDeviation: 600
  angle: 0
  angleDeviation: 360
  velocity: 100
  velocityDeviation: 30
  source: randomImage()
  // Get random image path
  function randomImage() {
    // Array of the image files
    var images = ["red.png", "blue.png", "green.png", "white.png", "yellow.png"]
    // Get random index of the array element
    var idx = Math.floor((Math.random() * 100)) % images.length
    // Return the relative image file path
    return ("Stars/" + images[idx])
  }
}

Now we need to add our Firework element to the Block element. Open Block.qml file and add declaration of the new element

Image
{
  id: block
  …
  Firework
  {
    id: firework
  }
  …
}

To launch fireworks on item going to visible state we need to add just one line of code

StateChangeScript { script: firework.burst(50); }

to "show" state

State
{
  name: "show"; when: show == true
  StateChangeScript { script: firework.burst(50)}
  PropertyChanges { target: block; opacity: 1 }
}

Launch application and press any key. Image appears on the screen with fireworks and sound effect.

This is a simple application, but this is a good playground to understand the principles of QML.

To learn more about QML you can extend this application by adding features. Who knows, maybe someday this sample will grow to a commercial app? Idea from me: educational software with letters, numbers, shapes, colors, etc.

---

This article originally appeared on the Intel AppUp(SM) developer program blog. A Russian version is available here

Thanks to Dmitry for allowing us to copy his tutorial.